#!/bin/csh -f
set verbose

rm -rf /repository
svnadmin create /repository

set all_versions=/product/*.*
set v1=$all_versions[1]
shift all_versions

cd /tmp
rm -rf product
cp -a $v1 product
find product -type d | xargs chmod 700
find product -type f | xargs chmod 600
mv product/doc/History .
svn import product file:///repository/product/trunk --file /tmp/History

rm -rf product
svn checkout file:///repository/product/trunk /tmp/product
cd /tmp/product
foreach v2 ($all_versions)
   cp -a $v2/* .
   find . -type d | xargs chmod 700
   find . -type f | xargs chmod 600
   diff -r $v1 $v2 > /tmp/difs
   grep -q '^Only in '$v1 /tmp/difs
   if ($status == 0) then
      foreach f (`grep '^Only in '$v1 /tmp/difs|sed 's@Only in '$v1'@@g'|sed 's@: @/@g'|sed 's@^/@@g'`)
         echo $f
         rm -rf $f
         svn delete $f
      end
   endif
   grep -q '^Only in '$v2 /tmp/difs
   if ($status == 0) then
      foreach f (`grep '^Only in '$v2 /tmp/difs|sed 's@Only in '$v2'@@g'|sed 's@: @/@g'|sed 's@^/@@g'`)
         echo $f
         svn add $f
      end
   endif
   diff -r $v1/doc/History $v2/doc/History | grep '^>' | cut -c3- | sed 's@ö@oe@g' | sed 's@°@o@g' >/tmp/History
   svn commit --file /tmp/History
   set v1=$v2
end